아두이노:RF통신 nRF24L01+ 편집하기 (부분)

== 예제 3: 양방향 통신 (송수신 전환) ==
한 노드가 송신과 수신을 번갈아 수행한다. 두 노드는 서로 다른 주소를 쓴다.<syntaxhighlight lang="c++">#include <SPI.h>
#include <nRF24L01.h>
#include <RF24.h>

RF24 radio(9, 10);

// 두 개의 주소: 송신자와 수신자는 아래 노드 순서를 반대로 하면 된다.
const byte addresses[][6] = {"NODE1", "NODE2"};  // 문자열이 아니라 바이트 배열로 채널을 잡는다. 5개 문자열만 가능.
// 배열 크기는 6개로 하고, 마지막에는 \0을 넣어 종료를 알린다.

bool isNode1 = true;  // 상대 노드에서는 false로 설정

void setup() {
  Serial.begin(9600);
  radio.begin();
  if (isNode1) {
    radio.openWritingPipe(addresses[1]);     // NODE2로 송신
    radio.openReadingPipe(1, addresses[0]);  // NODE1로 수신
  } else {
    radio.openWritingPipe(addresses[0]);
    radio.openReadingPipe(1, addresses[1]);
  }
  radio.setPALevel(RF24_PA_LOW);
}

void loop() {
  // --- 송신 단계 ---
  radio.stopListening();
  const char msg[] = "PING";
  radio.write(&msg, sizeof(msg));

  // --- 수신 단계 ---
  radio.startListening();
  unsigned long started = millis();
  while (!radio.available()) {
    if (millis() - started > 200) return;  // 200ms 타임아웃
  }
  char reply[32] = "";
  radio.read(&reply, sizeof(reply));
  Serial.print(F("응답 수신: "));
  Serial.println(reply);

  delay(500);
}</syntaxhighlight>